Les mémos

Fermer Tables

Fermer Requêtes

Fermer Formulaires

Fermer Etats

Fermer Modules

Fermer Base

Fermer Automation

Fermer Administration

Fermer Registre

Fermer String

Fermer Email CDO

Fermer Outlook

Fermer Net

Fermer Dates - Heures

Fermer Fichiers

Fermer Références

Fermer Vrac

Je débute...

Fermer La normalisation

Fermer VBA

Attention
Aucun support
par émail !

Utilisez le forum pour les questions/réponses concernant MsAccess et les codes que vous trouverez sur ce site.
Visites

   visiteurs

   visiteurs en ligne

Fichiers - Sélection fichier (MOL)

Parcourir et Sélectionner plusieurs fichiers (Mso Object Librairy)

 Sélectionner et retourner le chemin de un ou plusieurs fichiers séparés par un point-virgule.

La fonction a été  adaptée pour pouvoir indiquer un répertoire de départ et une extension.

 

Code :
Function fOpenFiles(Optional InitialDir As String = "", _
Optional InitialExt As String = "") As String
'/===========================================================
'/ Nécessite la référence microsoft office x.x object library
'/
'/ Pour indiquer un chemin de départ :
'/ X = fOpenFiles("F:\Clients")
'/
'/ Pour ouvrir dans le répertoire de la base :
'/ X = fOpenFiles("Me")
'/
'/ Pour indiquer l'extension :
'/ X = fOpenFiles("F:\",".txt")
'/===========================================================
Dim Dialogue As FileDialog
Dim Fichier As Variant, sPath As String, sExt As String
Set Dialogue = FileDialog(msoFileDialogOpen)
' traiter le répertoire initail
InitialDir = Trim(InitialDir)
If Left(UCase(InitialDir), 2) = "ME" Then
InitialDir = Application.CurrentProject.path & "\"
End If
If Len(InitialDir) > 0 And Right(InitialDir, 1) <> "\" Then
InitialDir = InitialDir & "\"
End If
'traiter l'extension
Select Case InitialExt
Case ".txt", ".mdb", ".xls", ".doc"
sExt = "*" & InitialExt
Case Else
sExt = "*.*"
End Select
'traiter les propriétés
With Dialogue
.AllowMultiSelect = True
.ButtonName = "Ouvrir"
.InitialFileName = InitialDir
.Filters.Clear
If sExt <> "*.*" Then
.Filters.add "Fichiers filtrés sur", sExt
Else
.Filters.add "Tous les fichiers", "*.*"
.Filters.add "Base de données Microsoft Access", "*.mdb"
.Filters.add "Tableur Microsoft Excel", "*.xls"
.Filters.add "Document Microsoft Word", "*.doc"
End If
.InitialView = msoFileDialogViewList
.Title = "Veuillez sélectionner les fichiers ..."
If .Show Then
For Each Fichier In .SelectedItems
fOpenFiles = fOpenFiles & Fichier & ";"
Next
End If
End With
If Len(fOpenFiles) > 0 Then
fOpenFiles = Left(fOpenFiles, Len(fOpenFiles) - 1)
End If
Set Dialogue = Nothing
End Function

Date de création : 02/11/2005 : 00:31
Dernière modification : 03/06/2011 : 18:16
Catégorie : Fichiers
Page lue 6930 fois


Imprimer l'article Imprimer l'article

Recherche



Lettre d'information
Pour avoir des nouvelles de ce site, inscrivez-vous à notre Newsletter.
Captcha
Recopier le code :
Au sujet de l'auteur
L'auteur qui fréquente (fréquentait) le forum microsoft.public.fr.access a eu le plaisir d'être nommé MVP Office-Access de janvier 2003 à décembre 2011.

Qui sont les MVP ?

Divers ;-)
Nous contacter

Haut